*cd [insérer chemin d'accès au fichier]
*use [insérer fichier - échantillon transversal], clear

*
foreach var of varlist fertpref_1 fertpref_2 fertpref_3 mcp_1 mcp_2 mcp_3 age_1 age_2 age_3 educattgen_1 educattgen_2 educattgen_3 marstat_1 marstat_2 marstat_3 score_1 score_2 score_3{
	replace `var'=. if `var'>=90
}

foreach var of varlist fertpref_1 fertpref_2 fertpref_3{
	replace `var'=. if `var'==3
}

*Créer un variable dénotant si l'utilisation de la contraception est permanente ou temporaire aux phases 2 et 3
gen mcpt=0 if mcp_2==0 & mcp_3==0
replace mcpt=1 if (mcp_2==1 & mcp_3==0) | (mcp_2==0 & mcp_3==1)
replace mcpt=2 if mcp_2==1 & mcp_3==1
label define mcpt 0 "Pas d'utilisation" 1 "Utilisation intermittente" 2 "Utilisation continue"
label values mcpt mcpt

*Créer un variable dénotant si les préférences en matière de fécondité sont stables entre les phases 1 et 2
gen fertpreft2=0 if fertpref_1==1 & fertpref_2==1
replace fertpreft2=1 if fertpref_1==2 & fertpref_2==1
replace fertpreft2=2 if fertpref_1==1 & fertpref_2==2
replace fertpreft2=3 if fertpref_1==2 & fertpref_2==2
label define fertpreft2 0 "OUI-OUI" 1 "NON-OUI" 2 "OUI-NON" 3 "NON-NON"
label values fertpreft2 fertpreft2

*ANALYSES
*Question: les préférences des femmes en matière de fécondité prédisent-elles leur adoption de la contraception?
*Dénominateur: femmes mariées n'utilisant pas de méthode contraceptive à la phase 1

*Pour cette analyse, nous utilisons des données des phases 1 et 3 seulement et pouvons dibc utiliser le poids panel1_3_weight
svyset [pw=panel1_3_weight]
svy: logit mcp_3 i.country i.fertpref_1 i.educattgen_1 age_1 score_1 if mcp_1==0 & pregnant_1==0 & (marstat_1==21 | marstat_1==22), or
margins, at(fertpref_1==1) at(fertpref_1==2)
marginsplot, recast(scatter) xscale(range(0.5 2.5)) ///
	title("Probabilité prédite d'adoption d'une méthode contraceptive moderne" "selon la préférence en matière de fécondité") ///
	ytitle("Probabilité prédite") xtitle("") ///
	xlabel(1 "Veut un (autre) enfant" 2 "Ne veut pas d'(autre) enfant") scheme(s1mono) ///
	note("Avec intervalles de confiance à 95%" "Adoption mesurée à la Phase 3. Préférence mesurée à la Phase 1.", size(vsmall))
graph export figure1-webinar-FR.pdf, replace
	
*Pour les analyses suivantes, nous utilisons des données des trois phases et pouvons donc utiliser le poids fullpanelweight
svyset [pw=fullpanelweight]
svy: logit mcp_3 i.country i.fertpreft2 i.educattgen_1 age_1 score_1 if mcp_1==0 & pregnant_1==0 & (marstat_1==21 | marstat_1==22), or
margins, at(fertpreft2=0) at(fertpreft2=1) at(fertpreft2=2) at(fertpreft2=3)
marginsplot, recast(scatter) xscale(range(0.5 4.5)) ///
	title("Probabilité prédite d'adoption d'une méthode contraceptive moderne" "selon le maintien de la préférence en matière de fécondité") ///
	ytitle("Probabilité prédite") xtitle("") ///
	xlabel(1 "OUI-OUI" 2 "NON-OUI" 3 "OUI-NON" 4 "NON-NON") scheme(s1mono) ///
	note( "Avec intervalles de confiance à 95%" "Adoption mesurée à la Phase 3. Préférence mesurée aux Phases 1 et 2." "OUI=veut un (autre) enfant" "NON=ne veut pas d'(autre) enfant", size(vsmall))
graph export figure2-webinar-FR.pdf, replace

svy: mlogit mcpt i.country i.fertpref_1 i.educattgen_1 age_1 score_1 if mcp_1==0 & pregnant_1==0 & (marstat_1==21 | marstat_1==22), rr
margins, at(fertpref_1==1) at(fertpref_1==2) predict(outcome(1)) predict(outcome(2))
marginsplot, recast(scatter) xscale(range(0.5 2.5)) ///
	title("Probabilité prédite d'adoption d'une méthode contraceptive moderne""selon la durée d'adoption et la préférence en matière de fécondité") ///
	ytitle("Probabilité prédite") xtitle("") ///
	xlabel(1 "Veut un (autre) enfant" 2 "Ne veut pas d'(autre) enfant") ///
	legend(order(1 "Adoption intermittente" 2 "Adoption continue")) scheme(s1mono) ///
	note("Avec intervalles de confiance à 95%" "Adoption et utilisation mesurées aux Phases 2 et 3. Préférence mesurée à la Phase 1.", size(vsmall))
graph export figure3-webinar-FR.pdf, replace